plugins {
    id 'me.modmuss50.mod-publish-plugin'
    id 'multiloader-loader'
    id 'net.neoforged.moddev'
}

neoForge {
    version = neoforge_version
    // Automatically enable neoforge AccessTransformers if the file exists
    def at = project(':common').file('src/main/resources/META-INF/accesstransformer.cfg')
    if (at.exists()) {
        accessTransformers.from(at.absolutePath)
    }
    parchment {
        minecraftVersion = parchment_minecraft
        mappingsVersion = parchment_version
    }
    runs {
        configureEach {
            systemProperty("neoforge.enabledGameTestNamespaces", mod_id.toString())
            ideName = "NeoForge ${it.name.capitalize()} (${project.path})" // Unify the run config names with fabric
        }
        client {
            client()
        }
        server {
            server()
        }
        gameTest {
            type = "gameTestServer"
            gameDirectory = project.file("build/gametest")
        }

        clientMixinExport {
            client()
            ideName = "NeoForge Client | Mixin Export (${project.path})"
            systemProperty("mixin.debug.export", "true")
        }
        serverMixinExport {
            server()
            ideName = "NeoForge Server | Mixin Export (${project.path})"
            systemProperty("mixin.debug.export", "true")
        }
    }
    mods {
        "${mod_id}" {
            sourceSet sourceSets.main
        }
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
    mavenLocal()

    maven {
        name = 'NeoForged'
        url = 'https://maven.neoforged.net/releases'
    }

    maven {
        name = "Mortuusars Github Maven"
        url = "https://raw.githubusercontent.com/mortuusars/resources/main/maven/"
    }
}

dependencies {
    jarJar(api("dev.ryanhcode.sable-companion:sable-companion-common-${project.minecraft_version}:[${project.sable_companion_version},)")) {
        version {
            prefer project.sable_companion_version
        }
    }

    compileOnly "maven.modrinth:distanthorizons:$rootProject.distant_horizons_version"
    runtimeOnly "maven.modrinth:distanthorizons:$rootProject.distant_horizons_version"
    compileOnly "maven.modrinth:backpacks-for-dummies:$rootProject.backpacks_for_dummies_version"

    compileOnly("com.simibubi.create:create-${minecraft_version}:${create_version}") { transitive = false }
    runtimeOnly("com.simibubi.create:create-${minecraft_version}:${create_version}") { transitive = false }
    compileOnly("net.createmod.ponder:ponder-neoforge:${ponder_version}+mc${minecraft_version}")
    runtimeOnly("net.createmod.ponder:ponder-neoforge:${ponder_version}+mc${minecraft_version}")
    compileOnly("dev.engine-room.flywheel:flywheel-neoforge-api-${minecraft_version}:${flywheel_version}")
    compileOnly("dev.engine-room.flywheel:flywheel-neoforge-${minecraft_version}:${flywheel_version}")
    runtimeOnly("dev.engine-room.flywheel:flywheel-neoforge-${minecraft_version}:${flywheel_version}")
    compileOnly("com.tterrag.registrate:Registrate:${registrate_version}")
    runtimeOnly("com.tterrag.registrate:Registrate:${registrate_version}")
    runtimeOnly("maven.modrinth:create-aeronautics:${aeronautics_version}")

    compileOnly("maven.modrinth:protomanlys-weather:${pmweather_version}")
    compileOnly("io.github.mortuusars.exposure:exposure-${minecraft_version}-neoforge:${exposure_version}") { transitive = false }
    compileOnly("maven.modrinth:jade:${project.jade_version}+neoforge") { transitive = false }
    compileOnly("maven.modrinth:jade-addons-forge:${project.jade_addons_version}+neoforge") { transitive = false }

    compileOnly "maven.modrinth:sodium:$sodium_version"
    runtimeOnly "maven.modrinth:sodium:$sodium_version"
    compileOnly("maven.modrinth:iris:$iris_version") { transitive = false }
    compileOnly("maven.modrinth:sodium-extras:neoforge-${minecraft_version}-$sodiumextras_version") { transitive = false }
    runtimeOnly("maven.modrinth:sodium-extras:neoforge-${minecraft_version}-$sodiumextras_version") { transitive = false }

    jarJar(api("foundry.veil:veil-neoforge-${project.minecraft_version}:${project.veil_version}") {
        exclude group: "maven.modrinth"
        exclude group: "me.fallenbreath"
    })
    compileOnly("foundry.imguimc:imguimc-neoforge-${project.minecraft_version}:${project.imguimc_version}")
}