туту

туттуру
2026-05-13 19:16:59 +02:00
commit 1da1a82143
22 changed files with 1265 additions and 0 deletions
@@ -0,0 +1,242 @@
+plugins {
+    id 'java-library'
+    id 'maven-publish'
+    id 'net.neoforged.moddev' version '2.0.141'
+    id 'idea'
+}
+
+tasks.named('wrapper', Wrapper).configure {
+    distributionType = Wrapper.DistributionType.BIN
+}
+
+version = mod_version
+group = mod_group_id
+
+configurations {
+    runtimeClasspath.extendsFrom localRuntime
+}
+
+sourceSets.main.resources {
+    srcDir('src/generated/resources')
+    exclude('**/*.bbmodel')
+    exclude('src/generated/**/.cache')
+}
+
+repositories {
+    mavenCentral()
+
+    exclusiveContent {
+        forRepository {
+            maven {
+                url = 'https://maven.blamejared.com/'
+                name = 'Jared Maven'
+            }
+        }
+        filter {
+            includeGroup('foundry.veil')
+            includeGroup('gg.moonflower')
+            includeGroup('io.github.ocelot')
+        }
+    }
+
+    exclusiveContent {
+        forRepository {
+            maven {
+                url = 'https://raw.githubusercontent.com/Fuzss/modresources/main/maven/'
+                name = 'Fuzs Mod Resources'
+            }
+        }
+        filter {
+            includeGroup('fuzs.forgeconfigapiport')
+        }
+    }
+
+    exclusiveContent {
+        forRepository {
+            maven {
+                url = 'https://maven.ryanhcode.dev/releases'
+                name = 'RyanHCode Maven'
+            }
+        }
+        filter {
+            includeGroup('dev.ryanhcode.sable')
+            includeGroup('dev.ryanhcode.sable-companion')
+        }
+    }
+
+
+
+
+}
+
+base {
+    archivesName = mod_id
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_21
+    targetCompatibility = JavaVersion.VERSION_21
+}
+
+neoForge {
+    version = project.neo_version
+
+    parchment {
+        mappingsVersion = project.parchment_mappings_version
+        minecraftVersion = project.parchment_minecraft_version
+    }
+
+    runs {
+        client {
+            client()
+            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
+        }
+
+        server {
+            server()
+            programArgument '--nogui'
+            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
+        }
+
+        gameTestServer {
+            type = 'gameTestServer'
+            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
+        }
+
+        data {
+            data()
+            programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
+        }
+
+        configureEach {
+            systemProperty 'forge.logging.markers', 'REGISTRIES'
+            logLevel = org.slf4j.event.Level.DEBUG
+        }
+    }
+
+    mods {
+        "${mod_id}" {
+            sourceSet(sourceSets.main)
+        }
+    }
+}
+
+dependencies {
+    compileOnly("dev.ryanhcode.sable:sable-common-${project.minecraft_version}:${project.sable_version}")
+
+    localRuntime("dev.ryanhcode.sable:sable-neoforge-${project.minecraft_version}:${project.sable_version}") {
+        exclude group: 'com.simibubi.create', module: "create-${project.minecraft_version}"
+        exclude group: 'net.createmod.ponder', module: 'ponder-neoforge'
+        exclude group: 'dev.engine-room.flywheel', module: "flywheel-neoforge-${project.minecraft_version}"
+        exclude group: 'com.tterrag.registrate', module: 'Registrate'
+    }
+}
+
+def rewriteVsCodeProgramArgs = { File sourceFile, File targetFile, File gameDir, String username ->
+    def rewritten = []
+    def replacedGameDir = false
+    def replacedUsername = false
+    def lines = sourceFile.readLines('UTF-8')
+
+    for (int i = 0; i < lines.size(); i++) {
+        if (lines[i] == '--gameDir' && i + 1 < lines.size()) {
+            rewritten << '--gameDir'
+            rewritten << gameDir.absolutePath
+            i++
+            replacedGameDir = true
+            continue
+        }
+
+        if (lines[i] == '--username' && i + 1 < lines.size()) {
+            rewritten << '--username'
+            rewritten << username
+            i++
+            replacedUsername = true
+            continue
+        }
+
+        rewritten << lines[i]
+    }
+
+    if (!replacedGameDir) {
+        rewritten << '--gameDir'
+        rewritten << gameDir.absolutePath
+    }
+
+    if (!replacedUsername) {
+        rewritten << '--username'
+        rewritten << username
+    }
+
+    targetFile.parentFile.mkdirs()
+    targetFile.text = rewritten.join(System.lineSeparator()) + System.lineSeparator()
+}
+
+tasks.register('prepareVsCodeClientRuns') {
+    dependsOn tasks.named('classes'), tasks.named('prepareClientRun')
+
+    inputs.file(layout.buildDirectory.file('moddev/clientRunProgramArgs.txt'))
+    outputs.files(
+            layout.buildDirectory.file('moddev/vscodeClientRunProgramArgs.txt'),
+            layout.buildDirectory.file('moddev/vscodeClientAltRunProgramArgs.txt')
+    )
+
+    doLast {
+        file('run').mkdirs()
+        file('run2').mkdirs()
+        file('run-data').mkdirs()
+        file('run-gametest').mkdirs()
+        file('run-server').mkdirs()
+
+        def modDevDir = layout.buildDirectory.dir('moddev').get().asFile
+        def sourceFile = new File(modDevDir, 'clientRunProgramArgs.txt')
+
+        rewriteVsCodeProgramArgs(sourceFile, new File(modDevDir, 'vscodeClientRunProgramArgs.txt'), file('run'), 'DevMain')
+        rewriteVsCodeProgramArgs(sourceFile, new File(modDevDir, 'vscodeClientAltRunProgramArgs.txt'), file('run2'), 'DevAlt')
+    }
+}
+
+def generateModMetadata = tasks.register('generateModMetadata', ProcessResources) {
+    def replaceProperties = [
+        minecraft_version      : minecraft_version,
+        minecraft_version_range: minecraft_version_range,
+        neo_version            : neo_version,
+        loader_version_range   : loader_version_range,
+        mod_id                 : mod_id,
+        mod_name               : mod_name,
+        mod_license            : mod_license,
+        mod_version            : mod_version
+    ]
+
+    inputs.properties replaceProperties
+    expand replaceProperties
+    from 'src/main/templates'
+    into 'build/generated/sources/modMetadata'
+}
+
+sourceSets.main.resources.srcDir generateModMetadata
+neoForge.ideSyncTask generateModMetadata
+
+publishing {
+    publications {
+        register('mavenJava', MavenPublication) {
+            from components.java
+        }
+    }
+    repositories {
+        maven {
+            url = "file://${project.projectDir}/repo"
+        }
+    }
+}
+
+tasks.withType(JavaCompile).configureEach {
+    options.encoding = 'UTF-8'
+}
+
+idea {
+    module {
+        downloadSources = true
+        downloadJavadoc = true
+    }
+}